Computations for the Hopf Bifurcation in Wright’s Equation

This document presents the content from the following sections:
	Section 2 	Preliminaries.
	Section 3.1 	Constructing a Newton-Like Operator 
	Appendix A 	Operator Norms
	Appendix B 	Endomorphism on a Compact Domain
	Appendix C	The Bounding Functions for Y(ϵ)
	Appendix D 	The Bounding Functions for Z(ϵ,r,ρ)
	Sections 3.2 	Explicit Contraction Bounds
	Appendix E	A Priori Bounds on Periodic Orbits
	Section 4.1 	A Proof of Wright’s Conjecture
	Appendix F	Implicit Differentiation
	Section 4.2 	Towards Jones’ conjecture

Section 2: Preliminaries

Linear Operator Definitions

We define the operator K as KK, and it is defined to operate on just the first 5 terms of a sequence. 
(The variable K cannot be used as it is a globally defined constant.)

KK=DiagonalMatrix[Table[(1/k) ,{k,1,5}]];

We define the operator (Subscript[U, ω]) as U[ω], and it is defined to operate on just the first 5 terms of a sequence.

U[w_]:=DiagonalMatrix[Table[Exp[-I k w],{k,1,5}]]

We define the shift operators (SuperMinus[σ]) and (SuperPlus[σ]) as Sn and Sp respectively. 
These are only defined to take the first 4 terms of a sequence as input.

Sn=DiagonalMatrix[Table[1,{k,1,4}],1];
Sp=DiagonalMatrix[Table[1,{k,1,4}],-1];

We define the operator (Subscript[L, ω]) as L[ω]. This is defined to operate on just the first 5 terms of a sequence, for which the first sequence term is exactly zero. 
WARNING: Do not multiply L with something with non-zero (Subscript[F, 1])term.

L[w_]:=(Sp.(Exp[-I w] IdentityMatrix[5]+U[w])+Sn.(Exp[I w] IdentityMatrix[5]+U[w]))

We define (Subscript[L, (Subscript[ω, 0])]) as L0.

L0:=L[π/2]

Definition 2.10 --- Approximate Solution

We define the approximate solution ((Subscript[(OverBar[α]), ϵ]), (Subscript[(OverBar[ω]), ϵ]), (Subscript[(OverBar[c]), ϵ])) as (a,w,c2).

a[ϵ_]:=π/2+((ϵ^2)/5)( 3π/2-1)
w[ϵ_]:=π/2-((ϵ^2)/5)
c2[ϵ_]:=(((2-I))/5)ϵ

Section 3: Local Results

Section 3.1: Constructing a Newton-Like Operator

Definition 3.1

In Definition 3.1 we define 
	A   := (Subscript[A, 0])+ ϵ (Subscript[A, 1])
	(SuperDagger[A]):= ((Subscript[A, 0])^(-1))- ϵ ((Subscript[A, 0])^(-1))(Subscript[A, 1]) ((Subscript[A, 0])^(-1))
and
	(Subscript[A, 0])(α,ω,c):= (Subscript[i, ℂ])(Subscript[A, 0,1]) [({{α}, {ω}})](Subscript[e, 1])+(Subscript[A, 0,*])c
(Subscript[A, 1])(α,ω,c):= (Subscript[i, ℂ]) (Subscript[A, 1,2]) [({{α}, {ω}})](Subscript[e, 2])+(Subscript[A, 1,*])c
In this Mathematica notebook, we do not explicitly define the operators A and (SuperDagger[A]). We do however define the component operators of (Subscript[A, 0]), ((Subscript[A, 0])^(-1)) and (Subscript[A, 1]).

We define the map (Subscript[A, 0,1]) as A01.

A01=(({{0, -π/2}, {-1, 1}}));

We define the map (Subscript[A, 1,2]) as A12.

A12=(1/5)(({{-2, (4-3 π)/2}, {-4, 2(2+π)}}));

We define the map (Subscript[A, 0,*])  as A0s.

A0s=(π/2)(I Inverse[ KK]+U[π/2]);

We define the map (Subscript[A, 1,*]) as A1s.

A1s=(π/2)L0;

Proposition 3.2

(((((2(Sqrt[10]))/5)))^(-1))//N

Appendix A: Operator Norms

We define the operator (OverHat[U]) as Uhat, and it is defined to operate on just the (2^nd) -(5^th) terms of a sequence.

Uhat=DiagonalMatrix[Table[If[k==1,0,(1/(1-I (k^(-1))Exp[-I k π/2]))],{k,1,5}]];

We define ((Subscript[A, 0,*])^(-1)):= (2/(i π))(OverHat[U]) K as A0sI

A0sI=(2/(I π))Uhat.KK;

For future use, we define ((((Subscript[A, 0,1])))^(-1)) as A01I.

A01I=Inverse[A01]

Proposition A.1

We check that the norm or ||(OverHat[U]) c|| is maximized when c=(Subscript[e, 5])

Table[Norm[(1/(1-I (k^(-1))Exp[-I k π/2]))],{k,2,10}]

We check that the norm or ||(OverHat[U]) K c|| is maximized when c=(Subscript[e, 2]).

Table[(1/k)Norm[(1/(1-I (k^(-1))Exp[-I k π/2]))],{k,2,10}]

Proposition A.2

We verify an inequality.

Max[{(1/5)(Sqrt[((45+5(Sqrt[17]))/2)]),((2(Sqrt[10]))/5)}]

Proposition A.3 -- An upper bound on: ((Subscript[A, 0])^(-1))(Subscript[A, 1])

We define an upper bound on ((Subscript[A, 0])^(-1))(Subscript[A, 1]) as A0A1.

A0A1=(({{0, 0, (1/2)(Sqrt[2+(π^2)/2])}, {0, 0, (1/(Sqrt[2]))}, {(8/(5π)), ((2(Sqrt[16+8π+5(π^2)]))/(5π)), (2/(Sqrt[5]))}}));

Appendix B: Endomorphism on a Compact Domain

Various Bounds

Definition B.1

We define (Subscript[Δ, α]), (Subscript[Δ, ω]) and (Subscript[δ, c]) as Da, Dw and δ.

Da[ϵ_,ra_]:=((ϵ^2)/5)(3 (π/2)-1)+ra
Dw[ϵ_,rw_]:=((ϵ^2)/5)+rw
δ[ϵ_,rc_]:=(2/(Sqrt[5]))ϵ+rc

The variables  (Subscript[Δ, α]^0), (Subscript[Δ, ω]^0) and (Subscript[δ, c]^0) are given as Da[ϵ,0], Dw[ϵ,0] and δ0[ϵ].

δ0[ϵ_]:=δ[ϵ,0]

Proposition B.4 - Rho

Used in the definition of (Subscript[C, 0]), we define (OverBar[(OverHat[U]) (Subscript[A, 1])]) as UA1.

UA1={(8/5),(2/5) (Sqrt[16+8π+5(π^2)]),((5 π)/2)};

We define (Subscript[C, 0]), (Subscript[C, 1]), (Subscript[C, 2]), and (Subscript[C, 3]) as C0, C1, C2 and C3.

C0[ϵ_,da_,dw_,rc_]:=((2(ϵ^2))/π)UA1.A0A1.{0,0, δ[ϵ,rc]}
C1[ϵ_]:=(5/(2 π))+((ϵ(Sqrt[10]))/π)
C2[ϵ_,rw_]:=Dw[ϵ,rw]((1+(π/2))+ϵ π)
C3[ϵ_,δ_,da_,dw_]:=da(2+δ)+2 dw(1+(π/2))+ϵ( π+2da+4 δ da+π dw δ+((π/2)+da)(δ^2))

We define the function C(ϵ,(Subscript[r, α]),(Subscript[r, ω]),(Subscript[r, c])) as ρ.

ρ[ϵ_,ra_,rw_,rc_]:=(1/(1-C1[ϵ] C2[ϵ,rw]))(C0[ϵ,Da[ϵ,ra],Dw[ϵ,rw],rc]+C1[ϵ]C3[ϵ,δ[ϵ,rc],Da[ϵ,ra],Dw[ϵ,rw]])

Appendix C: The bounding functions for Y(ϵ)

Y Bounds

These are the functions F((Subscript[x, ϵ])) exactly.

These functions are defined, approximated, but not used.

(Subscript[F, 1])[ϵ_,a_,w_,c2_]:=(I w+a Exp[-I w])+a ϵ (Exp[I w]+ Exp[-2 I w]) c2
(Subscript[F, 2])[ϵ_,a_,w_,c2_]:=(2 I w + a Exp[-2 I w ])c2 + a ϵ Exp[-I w]
(Subscript[F, 3])[ϵ_,a_,w_,c2_]:=a ϵ (Exp[-I w]+ Exp[- 2 I w ]) c2
(Subscript[F, 4])[ϵ_,a_,w_,c2_]:=a ϵ Exp[-2 I w ](c2^2)

F1[ϵ_]:=(Subscript[F, 1])[ϵ,a[ϵ],w[ϵ],c2[ϵ]]
F2[ϵ_]:=(Subscript[F, 2])[ϵ,a[ϵ],w[ϵ],c2[ϵ]]
F3[ϵ_]:=(Subscript[F, 3])[ϵ,a[ϵ],w[ϵ],c2[ϵ]]
F4[ϵ_]:=(Subscript[F, 4])[ϵ,a[ϵ],w[ϵ],c2[ϵ]]

F[ϵ_]:=Table[If[i≥ 5,0,(Subscript[F, i])[ϵ,a[ϵ],w[ϵ],c2[ϵ]]],{i,1,5}]

The polynomial Approximations of F((Subscript[x, ϵ]))

Proposition C.2 is delayed until the end of this section.

Proposition C.3 --- Bound on (Subscript[f, 1])

(Subscript[f, 1])[ϵ_]:=(π/2)((1/2)((Dw[ϵ,0])^2)+(1/6)((Dw[ϵ,0])^3))+Da[ϵ,0]Dw[ϵ,0]+ Da[ϵ,0]ϵ δ[ϵ,0]+((3π)/4)Dw[ϵ,0]ϵ δ[ϵ,0]

Proposition C.4 --- Bound on (Subscript[f, 2])

(Subscript[f, 2])[ϵ_]:=((π/2)+Da[ϵ,0])Dw[ϵ,0](δ[ϵ,0]+ϵ)+(1/2)δ[ϵ,0](2Dw[ϵ,0] +Da[ϵ,0])+ϵ Da[ϵ,0]

Proposition C.5 --- Bound on (Subscript[f, 3])

(Subscript[f, 3])[ϵ_]:=(1/2)((π/2)+Da[ϵ,0])((Sqrt[2])+3Dw[ϵ,0])ϵ δ[ϵ,0]

Proposition C.6 --- Bound on (Subscript[f, 4])

(Subscript[f, 4])[ϵ_]:=(1/5)((π/2)+Da[ϵ,0])(ϵ^3)

We define all the functions (Subscript[f, i]) as a single function

f[ϵ_]:=Table[If[i≥ 5,0,(Subscript[f, i])[ϵ]],{i,1,5}]

Theorem C.2 -- We compute a polynomial upper bound on (SuperDagger[A])F((Subscript[x, ϵ]))

We recall that
	(SuperDagger[A]):= ((Subscript[A, 0])^(-1))- ϵ ((Subscript[A, 0])^(-1))(Subscript[A, 1]) ((Subscript[A, 0])^(-1))
and
	(Subscript[A, 0])(α,ω,c):= (Subscript[i, ℂ])(Subscript[A, 0,1]) [({{α}, {ω}})](Subscript[e, 1])+(Subscript[A, 0,*])c
(Subscript[A, 1])(α,ω,c):= (Subscript[i, ℂ]) (Subscript[A, 1,2]) [({{α}, {ω}})](Subscript[e, 2])+(Subscript[A, 1,*])c
In order to compute (SuperDagger[A])F(ϵ), we break up the computation into its first and second order terms.

First Order Terms

We calculate the bound on ((Subscript[A, 0])^(-1))F(ϵ).

FirstOrderAW[ϵ_]:=(Abs[A01I].{1,1})(Subscript[f, 1])[ϵ]
FirstOrderC[ϵ_]:=Abs[A0sI].f[ϵ]

Second Order Terms

We may write
	((Subscript[A, 0])^(-1))(Subscript[A, 1])((Subscript[A, 0])^(-1))   =(((Subscript[A, 0,1])^(-1))+((Subscript[A, 0,*])^(-1)))((Subscript[A, 1,2])+(Subscript[A, 1,*]))(((Subscript[A, 0,1])^(-1))+((Subscript[A, 0,*])^(-1)))
			=((Subscript[A, 0,1])^(-1)) (Subscript[A, 1,*])((Subscript[A, 0,*])^(-1))+((Subscript[A, 0,*])^(-1))(Subscript[A, 1,2])((Subscript[A, 0,1])^(-1))+((Subscript[A, 0,*])^(-1))(Subscript[A, 1,*])((Subscript[A, 0,*])^(-1))

We compute the ((Subscript[A, 0,1])^(-1)) (Subscript[A, 1,*])((Subscript[A, 0,*])^(-1)) term.

SecondOrderAW[ϵ_]:=Abs[A01I].(Abs[A1s.A0sI][[1,2]]{1,1})(Subscript[f, 2])[ϵ]

We compute the ((Subscript[A, 0,*])^(-1))(Subscript[A, 1,2])((Subscript[A, 0,1])^(-1)) term.

SecondOrderC2[ϵ_]:=Abs[A0sI[[2,2]]  ]Abs[{1,I}.A12.A01I.{ 1,1}](Subscript[f, 1])[ϵ]

We compute the ((Subscript[A, 0,*])^(-1))(Subscript[A, 1,*])((Subscript[A, 0,*])^(-1)) term.

SecondOrderC[ϵ_]:=Abs[A0sI.A1s.A0sI].f[ϵ]

Total  (SuperDagger[A])F(ϵ) = Y Bound

AW[ϵ_]:=FirstOrderAW[ϵ]+ϵ SecondOrderAW[ϵ]
Cs[ϵ_]:=FirstOrderC[ϵ]+ϵ({0,SecondOrderC2[ϵ],0,0,0}+SecondOrderC[ϵ])

We define the Y functions

Ya[ϵ_]:=AW[ϵ][[1]]
Yw[ϵ_]:=AW[ϵ][[2]]
Yc[ϵ_]:=2Total[Cs[ϵ]]

Appendix D: The bounding functions for Z(ϵ,r,ρ)

Z Bounds

We delay Theorem D.1 until the end of the section

Proposition D.2

We define the function (Subscript[f, 1,α]).

f1a[ϵ_,dw_,δ_]:=dw+ ϵ ((δ ( 2 + δ))/2)

Proposition D.3

We define the function (Subscript[f, 1,ω]).

f1w[ϵ_,da_,dw_,δ_,ρ_]:=da+(π/2)dw+( (π/2)+da)(( ϵ δ )/2)(3 + ρ)

Proposition D.4

We define the function (Subscript[f, 1,c]).

f1c[ϵ_,da_,dw_,δ_]:=ϵ( da+((3π)/4)dw+((π/2)+da)δ)

Proposition D.5

We define the function (Subscript[f, *,α]).

fsa[ϵ_,rc_,dw_,δ_]:=(2/(π (Sqrt[5])))(rc+2 dw (((2 ϵ)/(Sqrt[5]))+ϵ)+ ϵ δ(4+δ))

Proposition D.6

We define the function (Subscript[f, *,ω]).

fsw[ϵ_,rc_,da_,dw_,δ_,ρ_]:=(5/(2 π ))(1 + (π/2))rc+(2/(Sqrt[5]))ϵ((1+(4/(Sqrt[5])))dw+(2/π)da)+(5/(2 π))da(rc + δ)+(2/π)ϵ((π/2)+da)((1/(Sqrt[5]))(δ+rc)+(5/4)(δ+(3/2)rc)+ρ (δ/(Sqrt[5])))

Proposition D.7

We define the function (Subscript[f, *,c]).

fsc[ϵ_,da_,dw_,δ_]:=((5/2)((1/2)+(1/π))dw + (da/(Sqrt[5])))+ ϵ((8/(π(Sqrt[5])))da+((2/(Sqrt[5]))+(25/8))dw+((4((π/2)+da)δ)/(π(Sqrt[5]))))

Theorem D.1

We define the matrix-valued function M  as below.

M[ϵ_,ra_,rw_,rc_,ρ_]:=(({{(Sqrt[1+(4/(π^2))]), 0}, {(2/π), 0}, {0, 1}})).(({{f1a[ϵ,Dw[ϵ,rw],δ[ϵ,rc]], f1w[ϵ,Da[ϵ,ra],Dw[ϵ,rw],δ[ϵ,rc],ρ], f1c[ϵ,Da[ϵ,ra],Dw[ϵ,rw],δ[ϵ,rc]]}, {fsa[ϵ,rc,Dw[ϵ,rw],δ[ϵ,rc]], fsw[ϵ,rc,Da[ϵ,ra],Dw[ϵ,rw],δ[ϵ,rc],ρ], fsc[ϵ,Da[ϵ,ra],Dw[ϵ,rw],δ[ϵ,rc]]}}))

We define the upper bound Z as below.

Z[ϵ_,ra_,rw_,rc_,ρ_]:=(ϵ^2)A0A1.A0A1+(IdentityMatrix[3]+ ϵ A0A1 ).M[ϵ,ra,rw,rc,ρ]

Section 3: Local Results

Section 3.2: Explicit Contraction Bounds

Theorem 3.7 and the definition of radii polynomials

Pa[ϵ_,ra_,rw_,rc_,ρ_]:=Ya[ϵ]+{1,0,0}.(Z[ϵ,ra,rw,rc,ρ]-IdentityMatrix[3]).{ra,rw,rc}
Pw[ϵ_,ra_,rw_,rc_,ρ_]:=Yw[ϵ]+{0,1,0}.(Z[ϵ,ra,rw,rc,ρ]-IdentityMatrix[3]).{ra,rw,rc}
Pc[ϵ_,ra_,rw_,rc_,ρ_]:=Yc[ϵ]+{0,0,1}.(Z[ϵ,ra,rw,rc,ρ]-IdentityMatrix[3]).{ra,rw,rc}

Proposition 3.10 (a)

We fix a collection of ϵ, r, and ρ for Proposition 3.10 (a).

WrightConjecture=
{ϵ->Interval[{0.029,0.029}],
ra->Interval[{0.13,0.13}],
rw->Interval[{0.17,0.17}],
rc->Interval[{0.17,0.17}],
ρW->Interval[{1.78,1.78}]};

We check that the hypothesis for Proposition B.4 is satisfied

ρW>ρ[ϵ,ra,rw,rc]/.WrightConjecture

We calculate all of the radii polynomials.

Pa[ϵ,ra,rw,rc,ρW]/.WrightConjecture
Pw[ϵ,ra,rw,rc,ρW]/.WrightConjecture
Pc[ϵ,ra,rw,rc,ρW]/.WrightConjecture

If the hypothesis of Theorem 3.7 is satisfied, and all of the radii polynomials are negative, then we have a proof of Proposition 3.10(a).

(ρW>ρ[ϵ,ra,rw,rc])&&(Pa[ϵ,ra,rw,rc,ρW]<0)&&(Pw[ϵ,ra,rw,rc,ρW]<0)&&(Pc[ϵ,ra,rw,rc,ρW]<0)/.WrightConjecture

Proposition 3.10 (b)

We fix a collection of ϵ, r, and ρ for Proposition 3.10 (b).

JonesConjecture={
ϵ->Interval[{0.09,0.09}],
ra->Interval[{0.1753,0.1753}],
rw->Interval[{0.0941,0.0941}],
rc->Interval[{0.3829,0.3829}],
ρJ->Interval[{1.5940,1.5940}]};

We check that the hypothesis for Proposition B.4 is satisfied

ρ[ϵ,ra,rw,rc]/.JonesConjecture

ρJ>ρ[ϵ,ra,rw,rc]/.JonesConjecture

We calculate all of the radii polynomials.

Pa[ϵ,ra,rw,rc,ρJ]/.JonesConjecture
Pw[ϵ,ra,rw,rc,ρJ]/.JonesConjecture
Pc[ϵ,ra,rw,rc,ρJ]/.JonesConjecture

If the hypothesis of Theorem 3.7 is satisfied, and all of the radii polynomials are negative, then we have a proof of Proposition 3.10(b).

(ρJ>ρ[ϵ,ra,rw,rc])&&(Pa[ϵ,ra,rw,rc,ρJ]<0)&&(Pw[ϵ,ra,rw,rc,ρJ]<0)&&(Pc[ϵ,ra,rw,rc,ρJ]<0)/.JonesConjecture

Proposition 3.15

We use numerical optimization (without interval arithmetic) to determine what radii to use.
We fix ϵ=0.10 and try to make r as small as possible.

ϵ316=0.10;
numopt316=NMinimize[{ra+rw+rc,
{Pa[ϵ,ra (ϵ^2),rw (ϵ^2),rc (ϵ^2),ρ[ϵ,ra (ϵ^2),rw (ϵ^2),rc (ϵ^2)]]<-10^-10,
Pw[ϵ,ra (ϵ^2),rw (ϵ^2),rc (ϵ^2),ρ[ϵ,ra (ϵ^2),rw (ϵ^2),rc (ϵ^2)]]<-10^-10,
Pc[ϵ,ra (ϵ^2),rw (ϵ^2),rc (ϵ^2),ρ[ϵ,ra (ϵ^2),rw (ϵ^2),rc (ϵ^2)]]<-10^-10,0<ra,0<rw,0<rc}
},{ra ,rw,rc }]/.ϵ->.10

Mathematica’s constrained numerical optimization function does not always produce a point for which all the radii polynomials are negative. So we check to see if in fact they are all negative.

Pa[ϵ,ra (ϵ^2),rw (ϵ^2),rc (ϵ^2),ρ[ϵ,ra (ϵ^2),rw (ϵ^2),rc (ϵ^2)]]/.numopt316[[2]]/.ϵ->ϵ316
Pw[ϵ,ra (ϵ^2),rw (ϵ^2),rc (ϵ^2),ρ[ϵ,ra (ϵ^2),rw (ϵ^2),rc (ϵ^2)]]/.numopt316[[2]]/.ϵ->ϵ316
Pc[ϵ,ra (ϵ^2),rw (ϵ^2),rc (ϵ^2),ρ[ϵ,ra (ϵ^2),rw (ϵ^2),rc (ϵ^2)]]/.numopt316[[2]]/.ϵ->ϵ316

We fix a collection of ϵ, r, and ρ for Proposition 3.15. 
Because of interval arithmetic, the r values need to be rounded up slightly.

TightEstimate={ϵ-> Interval[{.10,.10}],
ra->Interval[{0.0594,0.0594}],
rw->Interval[{0.0260,0.0260}],
rc->Interval[{0.4929,0.4929}],
ρT->Interval[{0.3191,0.3191}]};

We check that the hypothesis for Proposition B.4 is satisfied

ρT>ρ[ϵ,(ϵ^2)ra,(ϵ^2)rw,(ϵ^2)rc]/.TightEstimate

We calculate all of the radii polynomials.

Pa[ϵ,(ϵ^2)ra,(ϵ^2)rw,(ϵ^2)rc,ρT]/.TightEstimate
Pw[ϵ,(ϵ^2)ra,(ϵ^2)rw,(ϵ^2)rc,ρT]/.TightEstimate
Pc[ϵ,(ϵ^2)ra,(ϵ^2)rw,(ϵ^2)rc,ρT]/.TightEstimate

If the hypothesis of Corollary 3.13 is satisfied, and all of the radii polynomials are negative, then we have a proof of the first half of Proposition 3.15.

(ρT>ρ[ϵ,(ϵ^2)ra,(ϵ^2)rw,(ϵ^2)rc])&&(Pa[ϵ,(ϵ^2)ra,(ϵ^2)rw,(ϵ^2)rc,ρT]<0)&&(Pw[ϵ,(ϵ^2)ra,(ϵ^2)rw,(ϵ^2)rc,ρT]<0) &&(Pc[ϵ,(ϵ^2)ra,(ϵ^2)rw,(ϵ^2)rc,ρT]<0) /.TightEstimate

We also make sure that α>π/2

(1/5)(((3π)/2)-1)>ra/.TightEstimate

Remark 3.15

We check that the r and ρ values in Proposition 3.15 is less than those used in Proposition 3.10 (a) and (b).

((ϵ^2) ra/. TightEstimate)<(ra/. WrightConjecture)
((ϵ^2) rw/. TightEstimate)<(rw/. WrightConjecture)
((ϵ^2) rc/. TightEstimate)<(rc/. WrightConjecture)
(ρT/. TightEstimate)<(ρW/. WrightConjecture)

((ϵ^2) ra/. TightEstimate)<(ra/. JonesConjecture)
((ϵ^2) rw/. TightEstimate)<(rw/. JonesConjecture)
((ϵ^2) rc/. TightEstimate)<(rc/. JonesConjecture)
(ρT/. TightEstimate)<(ρJ/. JonesConjecture)

Appendix E: A Priori Estimates on Periodic Orbits

Proposition E.2

We define the function (Subscript[h, k])(ω) as h[k,w].

h[k_,w_]:=(((k^2)-1)/2)w+2 Sin[w]-2 k Sin[ k w]

If k=2, then clearly (Subscript[h, k])(ω)>0 for ω > 4. 
We use interval arithmetic to show that (Subscript[h, 2])(ω) is positive for ω ∈ [1.1,4.0].

h[2,Interval[{1.1,2.0}]]>0
h[2,Interval[{2.0,3.0}]]>0
h[2,Interval[{3.0,3.5}]]>0
h[2,Interval[{3.5,3.7}]]>0
h[2,Interval[{3.7,4.0}]]>0

If k=3, then clearly (Subscript[h, k])(ω)>0 for ω > 2. 
We use interval arithmetic to show that (Subscript[h, 2])(ω) is positive for ω ∈ [1.1,2.0].

h[4,Interval[{1.1,2}]]>0

If k=4, then clearly (Subscript[h, k])(ω)>0 for ω > 4/3. 
We use interval arithmetic to show that (Subscript[h, 2])(ω) is positive for ω ∈ [1.1,1.34].

h[4,Interval[{1.1,1.34}]]>0

Lemma E.3

γ[ϵ_,ω_]:=(1/2)+ϵ((2/3)+Max[{((Sqrt[2-2Sin[ω-(π/2)]])/2),(2/3)}])

Lemma E.4

We define the upper bound (SubStar[b])  to be BB.

BB[ϵ_,ra_,rw_]:= ((π/2-  rw)/(π/2+ ra))-(1/2)-ϵ((2/3)+(1/2)(Sqrt[2+2 rw]) )

We compute the values lower and upper bounds -- unscaled

lowB[ϵ_,ra_,rw_]:=BB[ϵ,ra,rw]-(Sqrt[((BB[ϵ,ra,rw])^2)- 2(ϵ^2)])
highB[ϵ_,ra_,rw_]:=BB[ϵ,ra,rw]+(Sqrt[((BB[ϵ,ra,rw])^2)-2 (ϵ^2)])

Lemma E.5

We compute a lower bound scaled with ϵ

lowBB[ϵ_,ra_,rw_]:=(1/ϵ)(BB[ϵ,ra,rw]-(Sqrt[((BB[ϵ,ra,rw])^2)-2 (ϵ^2)]))

Section 4: Global Results

Section 4.1: A proof of Wright’s Conjecture

Proposition 4.2

The maximum absolute value of a SOPS having α∈ [1.5706,π/2] is given by μ.

μ=Exp[Interval[{0.04,0.04}]]-1

Lemma 4.3

This lemma is concerned with α∈[1.5706,π/2].

αRange=Interval[{1.5706,(π/2)}];

We show that 0<(κ+1)(e^(-α κ))-1 for κ∈ [-μ,0), by showing that the RHS’s derivative is negative for κ∈ [-μ,0), and the observation that the RHS equals 0 when κ=0.

D[(κ+1)(E^(-α κ))-1,κ]/.{α-> αRange,κ-> -Interval[{0,Max[μ]}]}

We define maximum and minimum range of (SubPlus[t]) by TpMax and TpMin respectively.

TpMax=2+(1/(αRange));
TpMin=1+(1/(αRange))((Log[1+μ])/μ);

We define maximum and minimum range of (SubMinus[t]) by TnMax and TnMin respectively.

TnMax=3;
TnMin=1+(1/(αRange));

The maximum and minimum period length is given by respectively combining the maximum and minimum values of (SubPlus[t]) and (SubMinus[t]).

Lmin=TpMin+TnMin;
Lmax=TpMax+TnMax;

We obtain the appropriate range of frequencies ω by dividing 2π by the period length.

ωMax=((2 π)/Lmin)
ωMin=((2 π)/Lmax)

Lemma 4.5 - First Proof of -- A priori bounds for Wright’s Conjecture

This lemma derives bounds on the quantities ω, (SubStar[ϵ]), ||c||, and ||(K^(-1))c|| in order.

We show that ω∈[1.4219,1.6887].

Lemma 4.3 showed that ω ∈ [1.11,1.93]. We will obtain the desired bounds by showing that Line (4.3) of the paper cannot hold for ω in the interval [1.1000,1.4219] nor in the interval [1.6887,2.0000].

We define functions equal to the LHS and RHS of Line (4.3) in the paper, and then graph the functions over the relevant ranges.

LHS4p3[ω_,α_]:=ω(Sqrt[(((ω-α))^2)+2 α ω ( 1 - Sin[ω])])
RHS4p3[α_]:=((2 π)/(Sqrt[3]))(α^2)μ(1+μ)

Plot[{Max[LHS4p3[ω,αRange]],Min[RHS4p3[αRange]]},{ω,1.1,2}]

Essentially, we need to prove that the blue line (LHS) is above the orange line (RHS) for ω in the interval [1.1000,1.4219] as well the interval [1.6887,2.0000].

To show Line (4.3) is not satisfied for ω in the interval [1.6887,2.0000], it suffices to prove the following two points:
	□ The LHS is greater than the RHS at ω=1.6887 and α ∈ [1.5706,π/2].
	□ The derivative of the LHS with respect to ω is positive for  ω∈[1.6887,2.0000] and α∈ [1.5706,π/2]. 
	
We check this below.

LHS4p3[ω,αRange]> RHS4p3[αRange]/.ω->Interval[{1.6887,1.6887}]

0<D[LHS4p3[ω,αRange],ω]/.ω->Interval[{1.6887,2.0000}]

To show Line (4.3) is not satisfied for ω in the interval [1.1000,1.4219], it suffices to prove the following two points:
	□ The LHS is greater than the RHS at ω=1.4219 and α ∈ [1.5706,π/2].
	□ The derivative of the LHS with respect to ω is negative for  ω∈[1.1000,1.4219] and α∈ [1.5706,π/2]. 
	
We check this below. For the second point, we break the interval [1.1,1.4219] into two intervals [1.10,1.25] and [1.2500,1.4219].

LHS4p3[ω,αRange]> RHS4p3[αRange]/.ω->Interval[{1.4219,1.4219}]

0>D[LHS4p3[ω,αRange],ω]/.ω->Interval[{1.10,1.25}]
0>D[LHS4p3[ω,αRange],ω]/.ω->Interval[{1.25,1.4219}]

In conclusion, we have shown that ω must lie in the following interval:

ωRange= Interval[{1.4219,1.6887}];

Abs[ωRange-(π/2)]

We show that (SubStar[ϵ])≤ μ/(Sqrt[2]).

We check that the inequality in Line (4.4) from the paper is true.

(π/(ωRange (Sqrt[3])))αRange μ (1+μ)≤ ((2 ωRange-αRange)/(αRange))

αRange< 2 ωRange

We conclude with the estimate on ϵ from the paper.

ϵ0=μ/(Sqrt[2]);

We compute bounds on ||c|| and ||(K^(-1))c||.

These are the relevant values for (Subscript[r, α]) and (Subscript[r, ω]).

Abs[π/2-αRange]≤ Interval[{0.02,0.02}]
Abs[π/2-ωRange]≤ Interval[{0.1489,0.1489}]

We calculate an upper bound on (SubStar[b]).

BB[ϵ0,ra,rw]/.{ra->Max[Abs[αRange-(π/2)]],rw->Max[Abs[ωRange-(π/2)]]}

We calculate bounds on (SuperPlus[(SubStar[z])]) as in Line (2.10) from the paper (also see Proposition E.4), showing that (SuperPlus[(SubStar[z])]) ≥ 0.72.

highB[ϵ0,ra,rw]/.{ra->Max[Abs[αRange-(π/2)]],rw->Max[Abs[ωRange-(π/2)]]}

We compute an upper bound on ||(OverTilde[ c ])|| using Line (4.2), which is less than 0.09.

(π/(ωRange (Sqrt[3])))αRange μ(1+μ)< Interval[{0.09,0.09}]

We calculate bounds on (SuperMinus[(SubStar[z])])/ϵ as in Lemma E.5, showing that ||c|| ≤ 0.0796.

lowBB[ϵ0,ra,rw]/.{ra->Max[Abs[αRange-(π/2)]],rw->Max[Abs[ωRange-(π/2)]]}

We bound ||(K^(-1))c|| using Lemma 2.5(b).

ρBound=(2+((lowBB[ϵ0,ra,rw])^2))/BB[ϵ0,ra,rw]/.{ra->Max[Abs[αRange-(π/2)]],rw->Max[Abs[ωRange-(π/2)]]}

We adjust our bound on ||(K^(-1))c|| to be independent of ϵ.

ϵ0  ρBound

Theorem 4.6 - Proof of Wright’s Conjecture

We use numerical optimization (without interval arithmetic) to suggest what radii to use in Proposition 3.10(a). 
This (non-rigorous) calculation is not explicitly used in the paper.
This calculation does not appear earlier because some of the constraints are the result calculations made in Section 4.

ϵ311a=0.029;
ra311a=0.0002+Da[ϵ311a,0];
rw311a=0.15+Dw[ϵ311a,0];
rc311a=0.08+δ[ϵ311a,0];

numopt311a=NMaximize[
{rw,
Pa[ϵ,ra,rw,rc,ρ[ϵ,ra,rw,rc]]<0,
Pw[ϵ,ra,rw,rc,ρ[ϵ,ra,rw,rc]]<0,
Pc[ϵ,ra,rw,rc,ρ[ϵ,ra,rw,rc]]<0,
ra>  ra311a,
rw>rw311a,
rc>rc311a,rc>0,ρ[ϵ,ra,rw,rc]>0},
{ra ,rw ,rc }]/.ϵ->ϵ311a

Mathematica’s constrained numerical optimization function does not always produce a point for which all the radii polynomials are negative. So we check to see if in fact they are all negative.

Pa[ϵ,ra,rw,rc,ρ[ϵ,ra,rw,rc]]/.numopt311a[[2]]/.ϵ->ϵ311a
Pw[ϵ,ra,rw,rc,ρ[ϵ,ra,rw,rc]]/.numopt311a[[2]]/.ϵ->ϵ311a
Pc[ϵ,ra,rw,rc,ρ[ϵ,ra,rw,rc]]/.numopt311a[[2]]/.ϵ->ϵ311a

We check that the set S is contained inside (Subscript[B, ϵ])(r,ρ). The terms on the left are from Proposition 3.10(a).

WrightConjecture

(*(Subscript[r, α])*) Interval[{0.13,0.13}]≥ Interval[{0.0002,0.0002}]+Da[ϵ0,0]
(*(Subscript[r, ω])*) Interval[{0.17,0.17}]≥ Interval[{0.15,0.15}]+Dw[ϵ0,0]
(*(Subscript[r, c])*) Interval[{0.17,0.17}]≥ Interval[{0.08,0.08}]+δ[ϵ0,0]
(*ρ*) Interval[{1.78,1.78}]≥ Interval[{0.08,0.08}]

Appendix F: Implicit Differentiation

Lemma F.2

We define (Subscript[(OverHat[f]), ϵ,1]) as fϵ1.

fϵ1[ϵ_,da_,dw_,rc_,δ0_]:=
(1/2)δ0 ((Sqrt[2])da+3dw((π/2)+da))+rc ((π/2)+da)(1+δ0+(1/2)rc)

We define (Subscript[(OverHat[f]), ϵ,c]) as fϵc.

fϵc[ϵ_,da_,dw_,δ_,rc_,δ0_]:=(2/(π(Sqrt[5])))(2(da+(π/2)dw)+δ0 ((Sqrt[2])da+3 dw ((π/2)+da))+((π/2)+da)(4 rc+(δ^2)))

Prior Estimates

We recall our estimates from Proposition 3.16

ϵLocal=ϵ/.TightEstimate;
raLocal=ra/.TightEstimate;
rwLocal=rw/.TightEstimate;
rcLocal=rc/.TightEstimate;
ρLocal=ρT/.TightEstimate;
RA[ϵϵ_]:= raLocal ((ϵϵ)^2)
RW[ϵϵ_]:= rwLocal ((ϵϵ)^2)
RC[ϵϵ_]:=rcLocal ((ϵϵ)^2)

We define the upper bound (Subscript[ℨ, ϵ]) from Equation (4.6) as ZZ.

Zϵ[ϵ_]:=Z[ϵ,RA[ϵ],RW[ϵ],RC[ϵ],ρLocal]

Corollary F.3

We define our upper bound on (SuperDagger[A])(((∂F)/(∂ϵ))-Γ) as AFminusGamma

AFminusGamma[ϵ_]:=(IdentityMatrix[3]+ϵ A0A1).{(((1+(4/(π^2))))^(1/2))fϵ1[ϵ,Da[ϵ,RA[ϵ]],Dw[ϵ,RW[ϵ]],RC[ϵ],δ[ϵ,0]],(2/π)fϵ1[ϵ,Da[ϵ,RA[ϵ]],Dw[ϵ,RW[ϵ]],RC[ϵ],δ[ϵ,0]],fϵc[ϵ,Da[ϵ,RA[ϵ]],Dw[ϵ,RW[ϵ]],δ[ϵ,RC[ϵ]],RC[ϵ],δ[ϵ,0]]}

Lemma F.4

We define |α'| as Aprime, |ω'| as Wprime, and (a bound on) ||c'||=2|(Subscript[c', 2])|+2|(Subscript[c', 3])|as Cprime.

Aprime[ϵ_]:=(2/5)(((3π)/2)-1)ϵ
Wprime[ϵ_]:=(2/5)ϵ
Cprime[ϵ_]:=(2/(Sqrt[5]))+(2/(Sqrt[10]))ϵ+(18/(5(Sqrt[50])))(ϵ^2)

We define (Subscript[Q, ϵ]^0) as Qϵ0

Qϵ0[ϵ_]:={Aprime[ϵ],Wprime[ϵ],Cprime[ϵ]}

We define (Subscript[Q, ϵ]) as Qϵ

Qϵ[ϵ_]:=Qϵ0[ϵ]+AFminusGamma[ϵ]

Lemma F.5

We define (Subscript[M, ϵ]) and (Subscript[M', ϵ]) as Mϵ and MMϵ.

Mϵ[ϵ_]:=((1/(ϵ^2))AFminusGamma[ϵ])[[1]]
MMϵ[ϵ_]:=((1/(ϵ^2))Zϵ[ϵ] .Inverse[IdentityMatrix[3]-Zϵ[ϵ]].Qϵ[ϵ])[[1]]

Section 4: Global Results

Section 4.2: Work towards proving Jones’ Conjecture

Theorem 4.7

We compute if ϵ=0.1, then how big α must be, accounting for error given in TightEstimate.

a[ϵ]-(π/2)/.ϵ->Interval[{0.1,0.1}]
a[ϵ]-(π/2)-RA[ϵ]/.ϵ->Interval[{0.1,0.1}]

We check that α’>0 when ϵ =0.1

We check the last inequality stated in the proof to see if it is greater than 0.

0<(2/5)(((3π)/2)-1)ϵ-(ϵ^2)(Mϵ[ϵ]+MMϵ[ϵ])/.ϵ->Interval[{0.1,0.1}]

Theorem 4.9 -- Jones Conjecture

Finding some radii to be used in Proposition 3.10(b)

We use numerical optimization (without interval arithmetic) to suggest what radii to use in Proposition 3.10(b). 
This (non-rigorous) calculation is not explicitly used in the paper.
This calculation does not appear earlier because some of the constraints are the result calculations made in Section 4.

raOpt[ϵϵ_]:= Min[raLocal] (((ϵϵ))^2)

ϵ311b=0.09;
numopt311b=NMaximize[{rw,
Pa[ϵ,ra,rw,rc,ρ[ϵ,ra,rw,rc]]<-10^-10,
Pw[ϵ,ra,rw,rc,ρ[ϵ,ra,rw,rc]]<-10^-10,
Pc[ϵ,ra,rw,rc,ρ[ϵ,ra,rw,rc]]<-10^-10,
rc == δ[ϵ,0]+lowBB[ϵ,Da[ϵ,-raOpt[ϵ]],rw-Dw[ϵ,0]],
ra>0,rw>0,rc>0,ρ[ϵ,ra,rw,rc]>0},
{ra ,rw ,rc }]/.ϵ->ϵ311b

Mathematica’s constrained numerical optimization function does not always produce a point for which all the radii polynomials are negative. So we check to see if in fact they are all negative.

Pa[ϵ,ra,rw,rc,ρ[ϵ,ra,rw,rc]]/.numopt311b[[2]]/.ϵ->ϵ311b
Pw[ϵ,ra,rw,rc,ρ[ϵ,ra,rw,rc]]/.numopt311b[[2]]/.ϵ->ϵ311b
Pc[ϵ,ra,rw,rc,ρ[ϵ,ra,rw,rc]]/.numopt311b[[2]]/.ϵ->ϵ311b

Given the radii in Proposition 3.10 (b), we derive the needed values for Theorem 4.9

Below are computations used in determining the numbers given in the statement of the proposition.

We fix the ϵ we are using.

ϵJ=ϵ/.JonesConjecture

We check to see how large a range of α we could hope to prove using ϵ = 0.09

αJRange=a[ϵJ]-(π/2)-RA[ϵJ]

Given the (Subscript[r, w]) in Proposition 3.10(b), we calculate how far away ω can be from π/2.

ωJRange=rw-Dw[ϵ,0]/.JonesConjecture

Given the (Subscript[r, α]), (Subscript[r, ω]) above, we calculate how big to expect||c|| to be.

smallCmax=lowBB[ϵJ,ra,rw]/.{ra->αJRange,rw->ωJRange}

We calculate ρ

BB[ϵJ,ra,rw]/.{ra->αJRange,rw->ωJRange}

The following is the coefficient on ϵ which bounds ||(K^(-1))c||.

ρBound=(2+(smallCmax^2))/BB[ϵJ,ra,rw]/.{ra->αJRange,rw->ωJRange}

We adjust our bound on ||(K^(-1))c|| to be independent of ϵ.

ϵJ  ρBound

We  show (OverTilde[S])⊂(Subscript[B, ϵ])(r,ρ).

JonesConjecture

(*(Subscript[r, α])*) Interval[{0.1753,0.1753}]≥Interval[{0,0.00553}]+Da[ϵJ,0]
(*(Subscript[r, ω])*) Interval[{0.0941,0.0941}]≥ Interval[{0.0924,0.0924}]+Dw[ϵJ,0]
(*(Subscript[r, c])*) Interval[{0.3829,0.3829}]≥ Interval[{0.30232,0.30232}]+δ[ϵJ,0]
(*ρ*) Interval[{1.594,1.594}]≥ Interval[{0.32,.32}]

We check the next relevant inequalities.

Dw[ϵJ,0]+RW[ϵJ]≤ Interval[{0.0924,0.0924}]

δ[ϵJ,0]+RC[ϵJ]≤ Interval[{0.30232,0.30232}]

Theorem 4.10

We do a calculation indicative of what (Subscript[L, 2]) value to prove the theorem for.

(2ϵJ)(Sqrt[((6 ω)/π)])/.ω->(π/2)+Interval[{-0.0924,0.0924}]

We use Lemma 4.1 to check that the Fourier coefficients satisfy the bounds in Theorem 4.10

(Sqrt[(((π )/(6 ω)))])Interval[{0.302,0.302}]≤ Interval[{0.18,0.18}]/.ω->(π/2)+Interval[{-0.0924,0.0924}]

We check additional inequalities.

α<2 ω/.{α->(π/2)+ Interval[{0,0.00553}],ω->(π/2)+Interval[{-0.0924,0.0924}]}

Interval[{0.174,0.174}]≤ ((2 ω-α)/α)/.{α->(π/2)+ Interval[{0,0.00553}],ω->(π/2)+Interval[{-0.0924,0.0924}]}

We calculate bounds on (SuperPlus[(SubStar[z])]) as in Line (2.10) from the paper (also see Proposition E.4), showing that (SuperPlus[(SubStar[z])]) ≥ 0.595.

highB[ϵ,ra,rw]/.{ϵ-> Interval[{0.09,0.09}],ra->Interval[{0.00553,0.00553}],rw->Interval[{0.0924,0.0924}]}

We calculate bounds on (SuperMinus[(SubStar[z])]) / ϵ as in Lemma E.5, showing that || c|| ≤ 0.30226.

lowBB[ϵ,ra,rw]/.{ϵ-> Interval[{0.09,0.09}],ra->Interval[{0.00553,0.00553}],rw->Interval[{0.0924,0.0924}]}